- Registriert
- 1. Januar 2010
- Beiträge
- 12.354
- Lösungen
- 28
- Reaktionspunkte
- 64.886
- Punkte
- 1.103
Es gibt verschiedenste Wege, den Produktschlüssel einer Windows-Installation auszulesen.
Seit Windows 7 wird der komplette installierte Schlüssel allerdings nicht mehr angezeigt und ist lediglich über Drittprogramme oder Eingriffe in die Registry ermittelbar.
Auch das Backup des Product-Keys erfordert Drittprogramme.
Wer es etwas einfacher haben will, nutzt ein entsprechendes Script:
Gruß
Fisher
Seit Windows 7 wird der komplette installierte Schlüssel allerdings nicht mehr angezeigt und ist lediglich über Drittprogramme oder Eingriffe in die Registry ermittelbar.
Auch das Backup des Product-Keys erfordert Drittprogramme.
Wer es etwas einfacher haben will, nutzt ein entsprechendes Script:
Erstellt eine entsprechende Editor-Datei mit dem unten stehenden Inhalt:
(Hierzu einen beliebigen Editor öffnen, den Text in eine neue Datei kopieren und mit einem euch genehmen Namen und der Dateiendung "vbs" auf dem Desktop abspeichern.)
Ein Doppelklick auf die neu erstellte vbs Datei zeigt euch die installierte Seriennummer an und gibt euch die Möglichkeit, diese als Backup zu speichern.
(Hierzu einen beliebigen Editor öffnen, den Text in eine neue Datei kopieren und mit einem euch genehmen Namen und der Dateiendung "vbs" auf dem Desktop abspeichern.)
Code:
Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End FunctionEin Doppelklick auf die neu erstellte vbs Datei zeigt euch die installierte Seriennummer an und gibt euch die Möglichkeit, diese als Backup zu speichern.
Du musst angemeldet sein, um Bilder zu sehen.
Gruß
Fisher
Zuletzt bearbeitet:
